Here below a little program in Gosu that implements 2 classes (in fact, they are 3 + an extra utility Stopwatch class from my previous post http://carlosqt.blogspot.com/2011/05/stopwatch-class-for-java.html). There is the main class, called Fiborial (Fibo(nnacci)+(Facto)rial) that implements the Fibonacci and the Factorial algorithms in two ways, one Recursive (using recursion) and the other Imperative (using loops and states). The second class is just an instance class that does the same thing, but its there just to show the difference between static and instance classes, and finally the third one (which will not appear in other languages) is the Program class which has the static execution method "main".
You can also find 3 more little examples at the bottom. One prints out the Factorial's Series and Fibonacci's Series, the second one just shows a class that mixes both: static and instance members, and finally the third one that uses different return types (including java.math.BigInteger) for the Factorial method to compare the timing and result.
As with the previous posts, you can copy and paste the code below in your favorite IDE/Editor and start playing and learning with it. This little "working" program will teach you some more basics of the Programming Language.
There are some "comments" on the code added just to tell you what are or how are some features called. In case you want to review the theory, you can read my previous post, where I give a definition of each of the concepts mentioned on the code. You can find it here: http://carlosqt.blogspot.com/2011/01/new-series-factorial-and-fibonacci.html
The Fiborial Program
// Factorial and Fibonacci in Gosu
package com.series
uses com.series.Stopwatch
uses java.math.BigInteger
uses java.util.Scanner
uses java.lang.System
// static class
static class StaticFiborial {
// Static Field
private static var className: String = "Static Constructor"
// no available static constructor support
// you can initialize your static fields instead
/*static construct() { // error: constructors cannot be static
className = "Static Constructor";
print(className)
}*/
// Static Method - Factorial Recursive
static function factorialR( n : int ) : BigInteger {
if (n == 1) {
return BigInteger.ONE
}
else {
return BigInteger.valueOf(n).multiply(factorialR(n - 1))
}
}
// Class/Static Method - Factorial Imperative
static function factorialI( n : int ) : BigInteger {
var res = BigInteger.ONE
while (n > 1) {
res = res.multiply(BigInteger.valueOf(n))
n -= 1
}
return res
}
// Static Method - Fibonacci Recursive
static function fibonacciR( n : int ) : long {
if (n < 2) {
return 1
}
else {
return fibonacciR(n - 1) + fibonacciR(n - 2)
}
}
// Static Method - Fibonacci Imperative
static function fibonacciI( n : int ) : long {
var pre : long = 1
var cur : long = 1
var tmp : long = 0
for ( i in 2..n ) {
tmp = cur + pre
pre = cur
cur = tmp
}
return cur
}
// Static Method - Benchmarking Algorithms
static function benchmarkAlgorithm( algorithm : int, values : List<int>) {
var timer = new Stopwatch()
var testValue = 0
var facTimeResult : BigInteger = BigInteger.ZERO
var fibTimeResult : long = 0
// "Switch" Flow Control Statement
switch (algorithm)
{
case 1:
print("\nFactorial Imperative:")
// "For" Loop Statement
for (i in 0..values.size()-1) {
testValue = values.get(i).intValue()
// Taking Time
timer.start()
facTimeResult = factorialI(testValue)
timer.stop()
// Getting Time
print(" (${testValue}) = ${timer.getElapsed()}")
}
break
case 2:
print("\nFactorial Recursive:")
// "While" Loop Statement
var i = 0
while ( i < values.size() ) {
testValue = values.get(i).intValue()
// Taking Time
timer.start()
facTimeResult = factorialR(testValue)
timer.stop()
// Getting Time
print(" (${testValue}) = ${timer.getElapsed()}")
i++
}
break
case 3:
print("\nFibonacci Imperative:")
// "Do-While" Loop Statement
var i = 0
do {
testValue = values.get(i).intValue()
// Taking Time
timer.start()
fibTimeResult = fibonacciI(testValue)
timer.stop()
// Getting Time
print(" (${testValue}) = ${timer.getElapsed()}")
i++
} while (i < values.size());
break
case 4:
print("\nFibonacci Recursive:")
// "For Each" Loop Statement
for (item in values) {
testValue = item
// Taking Time
timer.start()
facTimeResult = fibonacciR(testValue)
timer.stop()
// Getting Time
print(" (${testValue}) = ${timer.getElapsed()}")
}
break
}
}
}
// Instance Class
class InstanceFiborial {
// Instance Field
private var className : String
// Instance Constructor
construct() {
this.className = "Instance Constructor"
print(this.className)
}
// Instance Method - Factorial Recursive
function factorialR( n : int ) : BigInteger {
// Calling Static Method
return StaticFiborial.factorialR(n)
}
// Instance Method - Factorial Imperative
function factorialI( n : int ) : BigInteger {
// Calling Static Method
return StaticFiborial.factorialI(n)
}
// Instance Method - Fibonacci Recursive
function fibonacciR( n : int ) : long {
// Calling Static Method
return StaticFiborial.fibonacciR(n)
}
// Instance Method - Factorial Imperative
function fibonacciI( n : int ) : long {
// Calling Static Method
return StaticFiborial.fibonacciI(n)
}
}
// Console Program
print("Static Class")
//Calling Static Class and Methods
//No instantiation needed. Calling method directly from the class
print("FacImp(5) = " + StaticFiborial.factorialI(5))
print("FacRec(5) = " + StaticFiborial.factorialR(5))
print("FibImp(11)= " + StaticFiborial.fibonacciI(11))
print("FibRec(11)= " + StaticFiborial.fibonacciR(11))
print("\nInstance Class")
//Calling Instance Class and Methods
//Need to instantiate before using. Calling method from instantiated object
var ff = new InstanceFiborial()
print("FacImp(5) = ${ff.factorialI(5)}")
print("FacRec(5) = ${ff.factorialR(5)}")
print("FibImp(11)= ${ff.fibonacciI(11)}")
print("FibRec(11)= ${ff.fibonacciR(11)}")
//Create a (generic) list of values to test
//From 5 to 50 by 5
var values = new List<int>()
var i = 5
while (i < 55) {
values.add(i)
i+=5
}
// Benchmarking Fibonacci
// 1 = Factorial Imperative
StaticFiborial.benchmarkAlgorithm(1, values)
// 2 = Factorial Recursive
StaticFiborial.benchmarkAlgorithm(2, values)
// Benchmarking Factorial
// 3 = Fibonacci Imperative
StaticFiborial.benchmarkAlgorithm(3, values)
// 4 = Fibonacci Recursive
StaticFiborial.benchmarkAlgorithm(4, values)
// Stop and exit
var sin = new Scanner(System.in)
var line = sin.nextLine()
sin.close()
And the Output is:
Printing the Factorial and Fibonacci Series
package com.series
uses java.math.BigInteger
uses java.lang.StringBuffer
static class Fiborial {
// Using a StringBuffer as a list of string elements
static function getFactorialSeries( n : int ) : String {
// Create the String that will hold the list
var series = new StringBuffer()
// We begin by concatenating the number you want to calculate
// in the following format: "!# ="
series.append("!")
series.append(n)
series.append(" = ")
// We iterate backwards through the elements of the series
for (i in n..0){
// and append it to the list
series.append(i)
if (i > 1)
series.append(" * ")
else
series.append(" = ")
}
// Get the result from the Factorial Method
// and append it to the end of the list
series.append(factorial(n).toString())
// return the list as a string
return series.toString()
}
// Using a StringBuffer as a list of string elements
static function getFibonnaciSeries( n : int ) : String {
// Create the String that will hold the list
var series = new StringBuffer()
// We begin by concatenating the first 3 values which
// are always constant
series.append("0, 1, 1")
// Then we calculate the Fibonacci of each element
// and add append it to the list
for (i in 2..n) {
if (i < n)
series.append(", ")
else
series.append(" = ")
series.append(fibonacci(i))
}
// return the list as a string
return series.toString()
}
static function factorial( n : int ) : BigInteger {
if (n == 1)
return BigInteger.ONE
else
return BigInteger.valueOf(n).multiply(factorial(n - 1))
}
static function fibonacci( n : int ) : long {
if (n < 2)
return 1
else
return fibonacci(n - 1) + fibonacci(n - 2)
}
}
// Printing Factorial Series
print("")
print(Fiborial.getFactorialSeries(5))
print(Fiborial.getFactorialSeries(7))
print(Fiborial.getFactorialSeries(9))
print(Fiborial.getFactorialSeries(11))
print(Fiborial.getFactorialSeries(40))
// Printing Fibonacci Series
print("")
print(Fiborial.getFibonnaciSeries(5))
print(Fiborial.getFibonnaciSeries(7))
print(Fiborial.getFibonnaciSeries(9))
print(Fiborial.getFibonnaciSeries(11))
print(Fiborial.getFibonnaciSeries(40))
And the Output is:
Mixing Instance and Static Members in the same Class
Instance classes can contain both, instance and static members such as: fields, properties, constructors/initializers, methods, etc.
// Fiborial.gs
package com.series
// Instance Class
class Fiborial {
// Instance Field
private var _instanceCount : int
// Static Field - no static constructor so it needs to be initialized here
private static var _staticCount : int = 0
// Instance Read-Only Property
// Within instance members, you can always use
// the "this" reference pointer to access your (instance) members.
property get InstanceCount() : int {
return this._instanceCount
}
// Static Read-Only Getter
// As with Static Methods, you cannot reference your class members
// with the "this" reference pointer since static members are not
// instantiated.
static property get StaticCount() : int {
return _staticCount
}
// Instance Constructor
construct() {
this._instanceCount = 0
print("\nInstance Constructor ${this.instanceCount}")
}
// Static Constructor
// not supported in Gosu. Constructor cannot be static.
/*static construct() {
staticCount = 0;
print("\nStatic Constructor $staticCount")
}
*/
// Instance Method
function factorial( n : int ) {
this._instanceCount += 1
print("\nFactorial(${n})")
}
// Static Method
static function fibonacci( n : int ) {
_staticCount += 1
print("\nFibonacci(${n})")
}
}
// FiborialExtrasApp.gsp
package com.series
// Calling Static Constructor and Methods
// No need to instantiate
Fiborial.fibonacci(5)
// Calling Instance Constructor and Methods
// Instance required
var fib = new Fiborial()
fib.factorial(5)
Fiborial.fibonacci(15)
fib.factorial(5)
// Calling Instance Constructor and Methods
// for a second object
var fib2 = new Fiborial()
fib2.factorial(5)
print("")
// Calling Static Property
print("Static Count = ${Fiborial.getStaticCount()}")
// Calling Instance Property of object 1 and 2
print("Instance 1 Count = ${fib.getInstanceCount()}")
print("Instance 2 Count = ${fib2.getInstanceCount()}")
And the Output is:
Factorial using java.lang.Long, java.lang.Double, java.math.BigInteger
package com.series
uses java.math.BigInteger
uses com.series.Stopwatch
// Long Factorial
function factorialInt64( n : int ) : long
{
if (n == 1)
return 1
else
return n * factorialInt64(n - 1)
}
// Double Factorial
function factorialDouble( n : int ) : double
{
if (n == 1)
return 1
else
return n * factorialDouble(n - 1)
}
// BigInteger Factorial
function factorialBigInteger( n : int ) : BigInteger
{
if (n == 1)
return BigInteger.ONE
else
return BigInteger.valueOf(n).multiply(factorialBigInteger(n - 1))
}
var timer = new Stopwatch()
var facIntResult : long = 0
var facDblResult : double = 0
var facBigResult = BigInteger.ZERO
print("\nFactorial using Int64")
// Benchmark Factorial using Int64
var i = 5
while (i < 55) {
timer.start()
facIntResult = factorialInt64(i)
timer.stop()
print(" (${i}) = ${timer.getElapsed()} : ${facIntResult}")
i += 5
}
print("\nFactorial using Double")
// Benchmark Factorial using Double
i = 5
while (i < 55) {
timer.start()
facDblResult = factorialDouble(i)
timer.stop()
print(" (${i}) = ${timer.getElapsed()} : ${facDblResult}")
i += 5
}
print("\nFactorial using BigInteger")
// Benchmark Factorial using BigInteger
i = 5
while (i < 55) {
timer.start()
facBigResult = factorialBigInteger(i)
timer.stop()
print(" (${i}) = ${timer.getElapsed()} : ${facBigResult}")
i += 5
}
And the Output is:
No comments:
Post a Comment